'only for RP2350 assembler. this does not work on RP2040

pio clear 1

pio assemble 1,".program test"
pio assemble 1,".line 0"
pio assemble 1,"set y,4"            'just a value 4 in Y
pio assemble 1,"mov isr,y"          'copy Y to isr
pio assemble 1,"jmp y--,next"       'y=y-1 always to next
pio assemble 1,"next:" ‘label
pio assemble 1,"mov rxfifo[y],isr"  'should program 4 in fifo [3]
pio assemble 1,"mov isr,y"          'copy Y to isr
pio assemble 1,"mov rxfifo[2],isr"  'should program 3 in fifo [2]
pio assemble 1,"jmp 0"              'repeat
pio assemble 1,".end program"
'pio assemble 1,".end program list"

f=1e6 '1MHz

'PIO(EXECCTRL a,b,c)
e=pio(execctrl gp0,0,31)   'default value, not actually changed

'PIO(SHIFTCTRL a,b,c,d,e,f,g,h,i,j)
sr=pio(shiftctrl 0,0,0,0,0,0,0,0,0,1) 'read individual RX, RX=4 deep
sw=pio(shiftctrl 0,0,0,0,0,0,0,0,1,0) 'write individual RX, RX=4 deep

'PIO(PINCTRL a,b,c,d,e,f,g)
p=pio(pinctrl 0,0,0,gp0,gp0,gp0,gp0) 'defaultvalue , not actually changed


'test the use of FIFO as individual registers

'fill the fifo with pre-determined values
pio init machine 1,0,f,p,e,sw,0   'init machine for writing to RX fifo
for i=0 to &h3                    'write the 4 RXFIFO registers
pio writefifo 1,0,i,&h100*(i+1)  'write values &h100, &h200, &h300, &h400
next

'check the values are written correctly
print "3 RXFIFO registers before running the program"
pio init machine 1,0,f,p,e,sr,0   'init machine for reading the RX fifo
for i=0 to 3      'read the 4 RXFIFO registers
  print i,hex$(pio(readfifo 1,0,i))  'verify they are correctly written
next
print

'run the PIO program. That should (continuously) write to reg 2 and 3 in the FIFO, but not alter register 0 and 1
pio start 1,0

'show the updated FIFO registers
print "3 RXFIFO registers after running the program"
for i=0 to 3   'read the 4 FIFO registers to see if the program works
  print i,hex$(pio(readfifo 1,0,i))
next

Saved 2021 bytes
3 RXFIFO registers before running the program
0      100
1      200
2      300
3      400

3 RXFIFO registers after running the program
0      100
1      200
2      3
3      4
>

pio assemble 1,"next:" ‘label

pio assemble 1,"next:" 'label