' pulse monitor
' 4 Apr 2014
' TassyJim
cls
samples=12
dim av(samples)
setpin 21, 6, beat
setpin 12, 8
beatTime = timer
gosub chart
do
testtime=timer
if (testtime-beattime)>6000 then
print @(1,10) "No pulse detected! "
beatTime = timer
pStart=0
endif
k$=inkey$
if k$="P" or k$="p" then savebmp "pulse.bmp"
if k$="C" or k$="c" then
cls
gosub chart
x=0
endif
loop

end

beat:
beatTimeNow = timer
beatPeriod=beatTimeNow-beatTime
beatTime=beatTimeNow
pulse 12, 40
if beatperiod > 5 and beatperiod < 3000 then
pulseRate=int(60000/beatPeriod+.5)
s= x mod samples
pav=pav-av(s)+ pulserate
av(s)=pulseRate
gosub clr_ahead
print @(1,10) "Pulse rate: ";pulseRate;" "
if pStart>0 then
pixel(x+40,300-pulserate) = yellow
endif
if pStart > samples then
av=int(pav/samples+0.5)
pixel(x+40,300-av) = red
print @(1,25) "Pulse av: ";av;" "
else
pStart = pStart +1
endif
x = (x+1) mod 360
endif
ireturn

chart:
cls
for ys = 0 to 200 step 20
y = 300 - ys
line (40,y) - (400, y), blue
print @(5,y-5) ys
next ys
return

clr_ahead:
line (x+40,300) - (x+50,50), black,BF
for ys = 0 to 200 step 20
y = 300 - ys
line (x+40,y) - (x+46, y), blue
next ys
return