new
100 ' Abagel - Guess a three letter word
200 ' Print instructions
202 cls
205 ? "All the words I know have 3 letters in them."
210 ? "I will think of a word, and you try to guess it."
215 ? "Each time, just type a three letter word (of your own)"
220 ? "and see what I say."
225 ?
230 ? "'Bagels' means none of your letters are in my word."
235 ? "But for each letter that is in my word, I will say"
240 ? "'Fermi' if it is in the right position, or 'Pico'"
245 ? "if it is in a different position.
250 ?
255 ? "But I will not tell you which letters I mean - you have"
260 ? "to use your head to figure that out!"
270 ?
280 ? "Type 'Q' to quit."
300 ' Read the word to be guessed
302 restore
304 read n
306 r=int(n*rnd(0))
307 for k=1 to r
308 read w$
309 next k
310 read t$
320 w$=ucase$(t$)
330 if mid$(w$,1,1)=mid$(w$,2,1) then 302
340 if mid$(w$,1,1)=mid$(w$,3,1) then 302
350 if mid$(w$,2,1)=mid$(w$,3,1) then 302
360 ?
370 ? "OK. I have a word."
380 ?
400 ' Input a guess
410 ?
420 ? "What is your guess?"
430 input t$
435 g$=ucase$(t$)
440 if len(g$)=3 then 470
442 if len(g$)<>1 then 450
444 if g$<>"Q" then 450
445 ?
446 ? "Bye."
447 ?
449 goto 999
450 ? "My word has three letters."
460 goto 410
470 if mid$(g$,1,1)=mid$(g$,2,1) then 510
480 if mid$(g$,1,1)=mid$(g$,3,1) then 510
490 if mid$(g$,2,1)=mid$(g$,3,1) then 510
500 goto 600
510 ? "No two letters are the same."
520 goto 410
600 ' Compare guess with computer's word
610 f=0
620 p=0
630 for j=1 to 3
640 for k=1 to 3
650 if mid$(g$,j,1)<>mid$(w$,k,1) then 720
660 if j=k then 700
670 ? "Pico ";
680 p=p+1
690 goto 720
700 ? "Fermi ";
710 f=f+1
720 next k
730 next j
740 if f+p>0 then 770
750 ? "Bagels ";
755 ?
760 goto 400
770 if f=3 then 800
780 ?
790 goto 400
800 ' Player has guessed the word
805 ?
810 ?
820 ? "You got it! My word is ";w$
830 ?
840 goto 300
900 ' Here is the data - first number is the number of words
901 data 152
905 data "try","had","hid","kid","few","lie","tie","buy"
910 data "sat","fat","hat","nap","pan","fan","sew","now"
915 data "pat","tap","tip","hut","hot","she","sum","met"
920 data "pot","apt","win","run","lip","pet","art","cup"
925 data "pun","cat","map","lap","out","dot","are","for"
930 data "and","but","tub","cry","let","wed","led","irk"
935 data "sky","cue","ten","wet","saw","was","cut","the"
940 data "far","you","him","her","erg","alp","ink","pen"
945 data "pin","dig","dew","amp","why","sun","son","opt"
950 data "pig","dog","bet","end","log","mid","hex","fix"
955 data "axe","dim","win","new","dry","mad","sad","dam"
960 data "may","say","yes","two","fed","fry","bid","top"
965 data "red","gay","hay","sly","fly","fit","sin","fin"
970 data "man","men","hen","sit","bit","hit","sag","gas"
975 data "nip","nib","bin","bag","lag","got","lot","use"
980 data "mat","bed","die","lad","lid","zen","wry","not"
985 data "ban","can","ran","tan","van","big","fig","jig"
990 data "don","won","ton","cot","jot","rot","bye","day"
995 data "tin","any","kit","has","age","old","yet","aim"
999 end